#lang racket/gui
(require graphics/turtles)

;;Órdenes LOGO
(define forward draw)
(define fd draw)

(define back (lambda (n) (draw (- n))))
(define bk back)

(define left turn)
(define lt turn)

(define right (lambda (gr) (turn (- gr))))
(define rt right)

(define clearscreen clear)
(define cs clear)
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;Interpretación à la LOGO
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

(define interpretacion-signo-elemental
  (lambda (char Paso Angulo)
    (cond
      ((char=? char #\l) (fd Paso))
      ((char=? char #\r) (fd Paso))
      ((char=? char #\+) (lt Angulo))
      ((char=? char #\-) (rt Angulo))
      (else
       #t
       ;(printf "error en interpretación del signo elemental ~a~n" char)
       )
      )
    ))
(define interpretacion-ristra
  (lambda (ristra P A)
    (for-each
     (lambda (char)
       (interpretacion-signo-elemental char P A)
       )
     (string->list ristra)
     )
    ))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;Sistema-DOL: 
;;1. Hay que contar con un vocabulario
(define vocabulario (list #\l #\r #\+ #\-))
;;2. Operación para formar expresiones compuestas
(define-syntax concatenar
  (syntax-rules ()
    [(concatenar x ...)
     (apply string-append
            (map
             (lambda (s)
               (cond
                 ((char? s) (string s))
                 ((string? s) s)
                 (else #f)
                 ))
             (list x ...))
            )
     ]
    ))
;;3. Predicado de tipo
(define-syntax ristra?
  (syntax-rules ()
    [
     (ristra? s)
     (andmap
      (lambda (char)
        (if (member char vocabulario)
            #t
            #f))
      (string->list s))
     ]
    ))
;;4. Reglas de producción
(define regla_L
  (lambda (signo)
    (if (char=? signo #\l)
        (concatenar #\l #\+ #\r #\+)
        #f)
    ))
(define regla_R
  (lambda (signo)
    (if (char=? signo #\r)
        (concatenar #\- #\l #\- #\r)
        #f)
    ))
(define regla_+
  (lambda (signo)
    (if (char=? signo #\+)
        (concatenar #\+)
        #f)
    ))
(define regla_-
  (lambda (signo)
    (if (char=? signo #\-)
        (concatenar #\-)
        #f)
    ))
;;5. Se aplica una de las tres reglas
(define aplicar-reglas
  (lambda (char)
    (or
     (regla_+ char)
     (regla_- char)
     (regla_L char)
     (regla_R char)
     )
    ))
;;6. Procedimiento auxiliar de transformación
(define transformar
  (lambda (lista-char)
    (if (null? lista-char)
        ""
        (concatenar
         (aplicar-reglas (first lista-char))
         (transformar (rest lista-char))
         )
        )
    ))
;;6. Método de transformación
(define derivacion_1
  (lambda (tesis)
    (if (ristra? tesis)
        (transformar (string->list tesis))
        (printf "~a ha de ser una tesis~n" tesis)
        )
    ))
;;7. Derivación de n aplicaciones
(define derivacion_n
  (lambda (tesis n)
    (let go ((i 0)
             (j n)
             (S tesis)
             )
      (if (= i j)
          S
          (go (add1 i) j (derivacion_1 S))
          )
      )
    ))

(define axioma (string #\l))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;Resultado de la interpretación LOGO
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(define interpretando
  (lambda (ristra P A N)
    (let* ((Paso P)
           (Angulo A)
           (n N)
           (S (derivacion_n ristra n))
           )
      (turtles)
      (sleep/yield 2)
      (turn 90)
      (interpretacion-ristra S Paso Angulo)
      )
    ))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(interpretando axioma 5 90 10)
